; Installer for prism2.device.
; Copyright © 2005-2008 Neil Cafferkey.
; $VER: "Install prism2.device" 1.3 (10.2.2008)


; Set constants

(set #dev-name "prism2.device")
(set #devs-source "Devs/networks")
(set @default-dest "DEVS:networks")
(set #pccard-name "pccard.library")
(set #libs-source "Libs")
(set #libs-dest "LIBS:")
(set #util-name "SetPrism2Defaults")
(set #c-source "C")
(set #c-dest "C:")
(set #firmware-source "Devs/Firmware")
(set #firmware-dest "DEVS:Firmware")

(set #kick-too-low-msg "Kickstart 3.0 or greater is required.")
(set #ask-firmware-prompt
   "Do you want to install firmware for the Hermes II chipset?"
)
(set #ask-firmware-help
   (cat "A firmware file is needed for a small number of PCMCIA cards,"
      " including certain cards made by Proxim, Thomson and Compex."
      " The file will be installed in \"" #firmware-dest "\"."
      " The firmware is ignored if unneeded, and no permanent changes"
      " are ever made to any card."
   )
)


; Check OS version isn't too old

(if (< (/ (getversion) 65536) 39)
   (abort #kick-too-low-msg)
)


; Check which OS we're running

(set #is-mos (= (run "Version \"MorphOS\"") 0))
(set #is-os4 (AND (>= (/ (getversion) 65536) 50) (NOT #is-mos)))


; Install pccard.library on OSs with PCMCIA support

(if (AND (NOT #is-os4) (NOT #is-mos))
   (copylib
      (source (tackon #libs-source #pccard-name))
      (dest #libs-dest)
      (help @copylib-help)
   )
)


; Install device

(if #is-os4 (set #devs-source (tackon #devs-source "OS4")))
(if #is-mos (set #devs-source (tackon #devs-source "MOS")))

(copyfiles
   (source
      (tackon #devs-source #dev-name)
   )
   (dest @default-dest)
   (help @copylib-help)
)


; Install the wireless parameter utility

(copylib
   (source (tackon #c-source #util-name))
   (dest #c-dest)
   (help @copylib-help)
)


; Install Hermes II firmware on OSs with PCMCIA support

(if (AND (NOT #is-os4) (NOT #is-mos))
   (if
      (if
         (= @user-level 2)
         (askbool
            (prompt #ask-firmware-prompt)
            (help #ask-firmware-help)
         )
         1
      )
      (copyfiles
         (source #firmware-source)
         (dest #firmware-dest)
         (all)
         (help @copylib-help)
      )
   )
)